Christopher Kane

Navigation

Disclaimer

The opinions expressed herein are my own personal opinions and do not represent my employer's view in anyway.

Axapta x++ Pick List Registration & packing slip post through code

This one is going to be a bit lengthy. We needed a way to Pick/Pack/Ship a sales order line using a single method call in Axapta. We used this code in a WCF service that allowed us to make a single call to pick, pack, and ship a single line from a sales order.

Below is the entire codebase I wrote (with comments) to accomplish this goal. If you have any questions please drop me an email.

// classDeclaration

class VendorIntegration_Shipment

{

    WMSOrderTransType_Output   wmsOrderTransType;

    WMSOrderTrans              wmsOrderTrans;

    DlvMode                    dlvMode;

    InventTable                inventTable;

    WMSRouteId                 pickListId;

    PackingSlipId              packingSlipId;

    CustDlvModeId              custDlvModeId;

    DlvModeId                  dlvModeId;

    str 10                     tradingPartner;

}

  

// new instance method

// Trading Partner: string used to determine calling vendor

// PickListId: Picklist from the sales order

// CustDlvModeId: Vendor's Shipping Method (we will look up ours from an xref table)

void new(str 10 _tradingPartner, WMSRouteId _pickListId, CustDlvModeId _dlvMode)

{

    VendorIntegrationModeOfDeliveryXRef vendDlvModeXRef;

    ;

    // trading partner is a string value we used to determine the vendor so we can look up cross reference information

    // specific to that vendor. Some vendors use different Shipping Method names than we do so we use a cross 

    // reference table to store their Shipping methods to ours.

    if(_tradingPartner == '' || _pickListId == '' || _dlvMode == '')

    {

        throw Global::error("One or more arguments were not supplied. (cstor).");

    }

  

    tradingPartner = _tradingPartner;

    pickListId = _pickListId;

    // Check to see if the supplied shipping method is different

    // from the Picking List.

    if(WMSPickingRoute::find(_pickListId).DlvModeId != _dlvMode)

    {

        // Check to see if we have this shipping method

        dlvMode = DlvMode::find(_dlvMode);

        if(dlvMode == null)

        {

            // Look up the supplied shipping method in the vendorXRef table.

            vendDlvModeXRef = VendorIntegrationModeOfDeliveryXRef::find(_tradingPartner, _dlvMode);

            if(vendDlvModeXRef != null)

            {

                //Wire it up

                dlvMode = DlvMode::find(vendDlvModeXRef.DlvModeId);

            }

            else

            {

                throw Global::error("The supplied shipping method could not be found (VendShippingXRef).");

            }

        }

    }

    else

    {

        dlvMode = DlvMode::find(_dlvMode);

    }

}

  

// Primary method to kick off the PICK/PACK/SHIP

// RecId: Specific record id from the WMSOrderTrans table generated AFTER PickList

// Qty: Quantity to ship

// InventSerialId: The serial # chosen to ship

// TrackingNumbers: x++ Container of tracking numbers supplied for this shipment

// ShipDate: The date of the shipment

public void receiveShipmentLine(int64 _recId, int _quantity, InventSerialId _inventSerialId, container _trackingNumbers, Date _shipDate)

{

    ;

    try

    {

        ttsBegin;

  

        // Look up the order transaction by picklist and recid

        select forUpdate wmsOrderTrans where wmsOrderTrans.RecId == _recId && wmsOrderTrans.routeId == pickListId;

  

        // Construct the Order Trans type object

        wmsOrderTransType = wmsOrderTransType::construct(wmsOrderTrans);

  

        // If the item is serialized, then compare and replace the inventory dimension. Custom method to check if Serialized Part

        if(InventTable::isSerialized(wmsOrderTrans.itemId)) this.updatePickListLineSerial(_inventSerialId);

  

        // Pick the line

        this.registerPickListLine();

  

        // Pack the line

        this.registerPackingSlipLine();

  

        //Save the tracking numbers

        this.saveTrackingNumbers(_trackingNumbers, _shipDate);

  

        ttsCommit;

    }

    catch (Exception::Error)

    {

        error("'Exception::Error' Unable to complete receiveShipmentLine. Transaction aborted.");

    }

}

  

// Used to update the PickList Registration

private void updatePickListLineSerial(InventSerialId _inventSerialId)

{

    InventDim           inventDimOrig;

    InventDim           inventDimNew;

    ;

  

    // If not empty

    if(_inventSerialId != '')

    {

        if(wmsOrderTrans != null)

        {

            // Look up the order transaction dimension

            inventDimOrig       = InventDim::find(wmsOrderTrans.inventDimId);

  

            if(_inventSerialId != inventDimOrig.inventSerialId)

            {

                // Find dim with the new serial number (our custom method to do the lookups)

                inventDimNew = InventDim::findOwnCondDispSiteLocSerial(inventDimOrig.configId,

                    inventDimOrig.InventSizeId, inventDimOrig.InventColorId, inventDimOrig.InventSiteId,

                    inventDimOrig.InventLocationId, _inventSerialId);

  

                // Move the registration to the new part

                wmsOrderTransType.moveReservation(inventDimNew);

            }

        }

        else

        {

            throw error("'Exception::Error' Unable to updatePickListLineSerial due to null wmsOrderTrans object. Transaction aborted.");

        }

    }

}

  

// PickList Register this line

private void registerPickListLine()

{

    container   pks;

    Map         dict;

    ;

    if(wmsOrderTrans != null)

    {

        // Create a Map (key/value pair)

        dict = new Map(Types::Int64, Types::Container);

        // Create a container

        pks = [wmsOrderTrans.orderId, wmsOrderTrans.recVersion];

        // Load the map with the recid and container

        dict.insert(wmsOrderTrans.RecId, pks);

        // Call finishPickingLines

        wmsOrderTransType.finishPickingLine('', wmsOrderTrans.inventDim(), EmplTable::userId2EmplId(curUserId()), TimeNow());

    }

    else

    {

        throw error("'Exception::Error' Unable to registerPickListLine due to null wmsOrderTrans object. Transaction aborted.");

    }

}

  

// Register the packing slip

private void registerPackingSlipLine()

{

    ;

    if(wmsOrderTrans != null)

    {

        // Register PackingSlip using a custom method we wrote (supplied below)

        packingSlipId = SalesFormLetter::createPackingSlipWithDlvMode(wmsOrderTrans.inventTransRefId, dlvMode.Code);

    }

    else

    {

        throw error("'Exception::Error' Unable to registerPackingSlipLine due to null wmsOrderTrans object. Transaction aborted.");

    }

}

  

// Method to save the tracking numbers for the shipment

public void saveTrackingNumbers(container _trackingNumbers, Date _shipDate)

{

    ShipCarrierPackage      shipPkgCarrier;

    container               trackMetaData;

    int                     pos;

    ;

    if(wmsOrderTrans != null)

    {

        pos = 1;

        while(pos <= conlen(_trackingNumbers))

        {

            trackMetaData = conpeek(_trackingNumbers, pos);

  

            shipPkgCarrier.SalesId                  = wmsOrderTrans.inventTransRefId;

            shipPkgCarrier.Weight                   = conpeek(trackMetaData, 2);

            shipPkgCarrier.ShipDate                 = _shipDate;

            shipPkgCarrier.PackingSlipId            = packingSlipId;

            shipPkgCarrier.ShipCarrierTrackingNum   = conpeek(trackMetaData, 1);

            shipPkgCarrier.CarrierId                = dlvMode.ShipCarrierId;

            shipPkgCarrier.insert();

            pos++;

        }

    }

    else

    {

        throw error("'Exception::Error' Unable to saveTrackingNumbers due to null wmsOrderTrans object. Transaction aborted.");

    }

}

  

// Custom PacklingSlip registration

public static PackingSlipId createPackingSlipWithDlvMode(SalesId _salesId, CustDlvModeId _dlvMode)

{

    // 06/12/2010: CCK

    // Needed to create a new packing slip method that allowed changing of the delivery mode.

    SalesFormLetter_PackingSlip packingSlip;

    SalesTable                  localSalesTable;

    DlvMode                     dlvMode;

    ;

    // Retrieve the dlvmode record

    dlvMode = dlvMode::find(_dlvMode);

    // Retrieve the sales record

    localSalesTable = SalesTable::find(_salesId);

    // Construct the SalesFormLeter using the Document Status Enum

    // The base class knows to construct the SalesFormLetter_PackingSlip from this enum

    packingSlip = SalesFormLetter::construct(DocumentStatus::PackingSlip);

  

    // Set a few override methods (this is only so we can override the Shipping Method set in the Sales Order)

    // There are times when the Shipping Method is changed @ shipment and allows us to override the

    // Shipping method set in the sales order. If you need more information contact me. You can remove

    // this code for your use.

    if(strUpr(localSalesTable.DlvMode) != strUpr(_dlvMode))

    {

        packingSlip.parmOverrideDlvMode(dlvMode.Code);

        packingSlip.parmOverrideShipCarrier(dlvMode.ShipCarrierId);

    }

    // Call update passing the the salesTable

    packingSlip.update(localSalesTable, SystemDateGet(), SalesUpdate::PickingList, AccountOrder::None, NoYes::No, NoYes::No);

    return packingSlip.getPackingListId();

}

Posted: Jun 22 2010, 08:35 by ckane | Comments (0)

Currently 0/5 Stars.
1
2
3
4
5

Filed under: Microsoft Axapta 2009

(SOLVED) Dynamics AX 2009 – Receive Purchase Order Line using x++ & .Net Business Connector

We needed to expose a WCF service so that our logistics vendors could execute a purchase order
line receipt. There were a lot of results returned from a google & yahoo search but a good portion
of them weren’t very specific. After hours of trial and error I came up with the x++ code below
that includes a serial number update through the Inventory Dimension.
public static void receivePurchLine(PackingSlipId _packSlipId, PurchId _purchId,
                                  Qty _qty, ItemId _itemId, LineNum _lineNum, str _inventLocation)
{
    PurchFormLetter purchFormLetter;
    ParmId parmId;
    PurchParmTable purchParmTable;
    PurchParmLine purchParmLine;
    PurchTable purchTable;
    PurchLine purchLine;
    InventDim currentInventDim;
    InventDim updatedInventDim;
    ;

    purchTable = PurchTable::find(_purchId);
    purchFormLetter = PurchFormLetter::construct(DocumentStatus::PackingSlip);
    purchFormLetter.createParmUpdate();
    purchFormLetter.createParmTable(purchParmTable, purchTable);
    purchParmTable.Num = _packSlipId;
    purchParmTable.insert();
    while select purchLine
        where purchLine.PurchId == purchTable.PurchId
    {
        purchParmLine.InitFromPurchLine(purchLine);
        purchParmLine.ParmId = purchParmTable.ParmId;
        purchParmLine.TableRefId = purchParmTable.TableRefId;
        if (purchLine.ItemId == _itemId && purchLine.LineNum == _lineNum)
        {
            currentInventDim = InventDim::find(purchLine.InventDimId);
            if (currentInventDim.RecId)
            {
                updatedInventDim = 
                        InventDim::findOrCreateOwnCondDispSiteLocation(currentInventDim.configId,
                                  currentInventDim.InventSizeId,
                                  currentInventDim.InventColorId,
                                  currentInventDim.InventSiteId,
                                  _inventLocation);
                if (!updatedInventDim.RecId)
                {
                    throw error('Unable to find or create destination inventory dimension');
                }
            }
            purchParmLine.ReceiveNow = _qty;
            purchParmLine.RemainAfter = purchLine.QtyOrdered - _qty;
            purchParmLine.InventDimId = updatedInventDim.inventDimId;
        }
        else
        {
            purchParmLine.ReceiveNow = 0;
            purchParmLine.RemainAfter = purchLine.QtyOrdered;
        }
        purchParmLine.setQty(DocumentStatus::PackingSlip, false, true);
        purchParmLine.setLineAmount();
        purchParmLine.insert();
    }

    purchFormLetter.proforma       (false);             // proforma ?
    purchFormLetter.printFormLetter(false);            // print ?
    purchFormLetter.specQty        (PurchUpdate::All);  // what to update?
    purchFormLetter.transDate      (today());           // update date
    purchFormLetter.run();
}

Posted: Jan 17 2010, 08:14 by ckane | Comments (1)

Currently 5/5 Stars.
1
2
3
4
5

Filed under: Microsoft Axapta 2009

Axapta Business Connector To Import Address and Performance

So, importing addresses the correct way, according to professionals we have talked to, is to import by using the DirParty and PartyId values to do the inserts. Let me tell you this is DOG slow and performance is horrible. If you bypass and just use the AddrTableId from say the CustTable performance is a huge improvement.

I don’t know what Microsoft (or it’s previous developers were thinking) but the DirParty and DirPartyRelationships need some SERIOUS improvement in performance or just get rid of them all together.

Imports using the Business Connector for any other data other than Addresses FLY!

Posted: Aug 03 2009, 13:14 by ckane | Comments (0)

Currently 0/5 Stars.
1
2
3
4
5

Filed under: Microsoft Axapta 2009

AOS Server Service Fault

Discovered a problem with the Axapta AOS Server service stopping and faulting:

Faulting application Ax32Serv.exe, version 5.0.1000.52, time stamp 0x490c68d8, faulting module Ax32Serv.exe, version 5.0.1000.52, time stamp 0x490c68d8, exception code 0xc0000005, fault offset 0x00000000004be844, process id 0x3a0, application start time 0x01c992a34fef6bbc.

The error was discovered when attempting to run the Label Editor. We deleted all the .ali .alc .ald files and restarted the service.

Posted: Jul 11 2009, 02:14 by ckane | Comments (0)

Currently 0/5 Stars.
1
2
3
4
5

Filed under: Microsoft Axapta 2009

Getting values from another table to wire up into a form’s fields

I had to develop a unique situation where a table in axapta needed to be populated using some fields from a newly created table. The problem was that the table ‘ConfigTable’ and it’s associated form allowed the user to enter in information via a textbox/string and we wanted the form to populate this data from another table. We were worried that people won’t do the due diligence to check and see if the ‘ConfigId’ already existed nor would the follow formatting rules. So what we did is was created a new “OwnerMasterTable” table that contained all the unique “ConfigId” and “Name” fields we then changed the form to do a lookup.

We hid the first two fields in the ConfigTable form (ConfigId and Name) and added a new field to the form: OwnerId. Using this field, we were able to lookup the values from the “OwnerMasterTable” and populate the “hidden” values in the form that would then be used to populate the "ConfigTable”. We did it by overwriting the textChange event on the OwnerId so that we could wireup the hidden fields and not break the existing “ConfigTable” schema.

public void textChange()
{
    super();
    // We know what the text is that was selected so lets wire up the configTable's ConfigId value
    configtable.ConfigId = this.text();
    // We need to do a quick lookup of the ownerMasterTable so we can
    // can get the correct Name to wireup to the ConfigTable Name property using the text from above.
    select ownerMasterTable where ownerMasterTable.OwnerId == this.text();
    configtable.Name = ownerMasterTable.Name;
}

Posted: Jul 11 2009, 02:10 by ckane | Comments (0)

Currently 0/5 Stars.
1
2
3
4
5

Filed under: Microsoft Axapta 2009

Dealing with lists in .Net Business Connector and how to get around it

So I had the pleasure of having to deal with Lists and Containers in the .Net Business Connector and it was NOT a pleasurable experience. Axapta uses lists and containers and trying to use them in C# was a complete nightmare because using either type always generated a ‘Bad Container’ error.

The Axapta SDK states that a List is equivalent to a generic list in C#….this is incorrect Axapta doesn’t support generics. The real c# array to use is the ArrayList because it is not of generic type. When you go to pass the ArrayList into the method you must use the following code to do so: list.ToArray(typeof(string)). Otherwise you will get an invalid parameter exception but this still generated a ‘Bad Container’ exception.

The Axapta SDK states that you can use a AxaptaContainer to pass into a method where the container object is being used but unfortunately COM interop doesn’t translate it correctly and once again throws a ‘Bad Container’ exception.

The solution? I ended up using a comma separated string to pass into a new method and used the Axapta ‘strSplit’ Global method to split the string into an Axapta List.

Below is the x++ method that I created

server static void finishMultiMDSi(str _pickListIds)
{
    List list = new List(Types::String);
    ;
    if (_pickListIds)
    {
        // We pass in a comma sep string, we split the string into a list
        list = strSplit(_pickListIds, ',');
        // Pass the list into the finishMulti method to post the pick list
        WMSPickingRoute::finishMulti(list.pack());
    }
}

Posted: Jul 11 2009, 02:10 by ckane | Comments (0)

Currently 0/5 Stars.
1
2
3
4
5

Filed under: Microsoft Axapta 2009

Executing Pick List Registration in code

So I needed to post the pick list registration outside of Axapta. After quite a bit of time I found out exactly where it is done and it’s very simple.

WMSPickingRoute::finishMulti() is the method that is used to post the pick list registration and all the method takes is a container of PickingRouteId’s. You simply pass in all the PickingRouteId’s that you need to be Registered and the logic in this method takes care of it.

Posted: Jul 11 2009, 02:06 by ckane | Comments (0)

Currently 0/5 Stars.
1
2
3
4
5

Filed under: Microsoft Axapta 2009

Recent posts

Tags

Categories

Navigation

Pages

Archive

Blogroll

Disclaimer

Axapta x++ Pick List Registration & packing slip post through code

(SOLVED) Dynamics AX 2009 – Receive Purchase Order Line using x++ & .Net Business Connector

Axapta Business Connector To Import Address and Performance

AOS Server Service Fault

Getting values from another table to wire up into a form’s fields

Dealing with lists in .Net Business Connector and how to get around it

Executing Pick List Registration in code